ZVSE
ERMS_ScriptName=Arcane Tower
ERMS_ScriptAuthor=SergRoj (original version's author is Donald X)
ERMS_ScriptVersion=1.0.0
ERMS_ScriptDate=25.09.2004
ERMS_ScriptERMVersion=2.70
ERMS_ScriptLanguage=English
ERMS_ScriptUsedVariables=v1-v9;z1;z403mustn'tbechanged
ERMS_ScriptUsedFlags=1-2
ERMS_ScriptUsedFunctions=FU620
_WARNING_#1=IMPORTANT! This file is not in a plain text format. NEVER use any editor except ERM_S for making any kind of changes!
ERMS_PoweredBy=ERM Scripter v. 2003.5.19.2212
sergroj@hotbox.ru 

_DECLARATION_Initialization= 
!#VRz403:S^Arcane Tower^; 
!#HT63/9:T403; 


_DECLARATION_OB Arcane tower trigger=
!?OB63/9&1000;
!!UN:P104/?y1;
!!IF&y1=1:M^A ghost floats down a staircase and glides up to you. It floats there, flickering, regarding you. At last it speaks. "It is well that you came here, traveller. I can help you."^;
!!IF&y1=1:Q1^The ghost continues. "I can make you strong, give you power - perhaps as much power as I have! But it will cost you dearly. I can give you skill at attack, defense, spellcasting, or knowledge... in return, I require the same. One for one. Are you interested?"^;
!!IF&y1=1/-1:M^"Ah, traveller, you will know one day that you have erred."^;
!!HE-1&1/y1=1:W?y2/1;
!!IF&1/y1=1/y2<130:V1/0 M^"Than come back tomorrow... You are too tired today."^;
!!IF&y1<>1:V1/0; 
!!VRz-1&1:S^Attack^;
!!VRz-2&1:S^Defence^;
!!VRz-3&1:S^Spell Power^;
!!VRz-4&1:S^Knowledge^;
!!VRz1&1:S^"Of course. Who wouldn't be? What do you want to learn?"^;
!!IF&1:G1/1/1/1/-1/-2/-3/-4/0/0/0/0/0/0/0/0;
!!VRz1&1:S^"What will you pay for that?"^;
!!IF&1/v1=1:G1/2/1/1/-2/-3/-4/0/0/0/0/0/0/0/0/0;
!!IF&1/v1=2:G1/2/1/1/-1/-3/-4/0/0/0/0/0/0/0/0/0;
!!IF&1/v1=4:G1/2/1/1/-1/-2/-4/0/0/0/0/0/0/0/0/0;
!!IF&1/v1=8:G1/2/1/1/-1/-2/-3/0/0/0/0/0/0/0/0/0;
!!VRv1&1/v1=4:S3;
!!VRv1&1/v1=8:S4;
!!VRv2&1/v2=4:S3;
!!VRv2&1/v2=8:S4;
!!VRv2&v2>=v1:+1;
!!VRv3&1:S0 -v1;
!!VRv4&1:S0 -v2;
!!VRz1&1:S^"Look what you'll have. Are you sure you still want to learn {^+zv3+^} skill and pay with the {^+zv4+^} skill?"^;
!!VRv3&1:Sv1 +30;
!!VRv4&1:Sv2 +30;
!!VRv1&1:+5;
!!VRv2&1:+5;
!!HE-1&1:F?v6/?v7/?v8/?v9/1;
!!VRv5&1:Svv2;
!!VRv5&1/v2<8:+1;
!!HE-1&1:F?v6/?v7/?v8/?v9;
!!IF&1/v5<=1:M^"You can't trick me! You have none to pay!"^;
!!IF&1/v5<=1:V1/0;
!!IF&1:V2/1;
!!FU620&1:P;
!!IF&1/-2:V1/0 M^"Ah, traveller, you will know one day that you have erred."^;
!!DO620/3/v5/1&1/2/v5>=3:P;
!!IF&1:M^The ghost admires its handiwork. "Your new powers are affecting you. I can see the change already..."^;


_DECLARATION_Function 620= Change skills
!?FU620;
!!HE-1&2:W?y1/1;
!!IF&2/y1<130:V1/0;
!!VRvv1&1/2:+1;
!!VRvv2&1/2:-1;
!!IF&1/2:Q2/v3/vv1/v4/vv2/2/z1;
!!HE-1&1/2:Fv6/v7/v8/v9 Wd-130;
!!VRz1&1/2:S^"Excellent! The same trade again?"^;
!!UN&1/2:R1;
!!IF&-1/2:V2/0 M^The ghost admires its handiwork. "Your new powers are affecting you. I can see the change already. {But} {you} {are} {too} {tired.} {Let's} {continue} {tomorrow}..."^;